<% @LANGUAGE=VBscript %>
<%
Response.ContentType = "application/msword"
Response.Expires = 0
%>
<%
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
' MyDesign Haber
' http://www.mydesign.gen.tr
' Word Dosyası Oluşturma Kodları
' Son Düzenleme: 16 Ekim 2007 (v0.5)
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
'// Sayfanın önbellekten alnması önleniyor
Response.Buffer = True
Response.Expires = -1
Response.ExpiresAbsolute = Now() - 2
Response.AddHeader "pragma","no-cache"
Response.AddHeader "cache-control","private"
Response.CacheControl = "No-Store"
'// Değişkenler tanımlanıyor
Dim strHaberMetni
Dim SQL
Dim intHaberOkunmaSayisi
Dim intHaberKategorisi
Dim intHaberEditor
Dim dtmHaberTarihi
Dim strHaberOzet
Dim blnHaberVar
Dim strHaberBaslik
Dim strHaber
Dim blnResim
'// Formdan veriler alınıyor
strHaber = Temizle(Trim(Request.QueryString("haber")))
blnHaberVar = True
'// Haber verisinin olup olmadığı ve verinin sayı olup olmadığı kontrol ediliyor
If strHaber = "" Or IsNumeric(strHaber) = False Then
blnHaberVar = False
Else
'// Veri, sayıysa veritabanı kontrolü yapılıyor
kdGenel.Open "SELECT * FROM tblHaberler WHERE durum=True AND onay=True AND haberID = "& CInt(strHaber) &"", adoCon, 1, 3
'// Uygun kayıt bulunamadıysa mesaj yazılıyor
If kdGenel.EOF Then
blnHaberVar = False
'// Kayıt varsa haber gösteriliyor
Else
'// Haberin bilgileri alınıyor
intHaberOkunmaSayisi = kdGenel("okunma")
strHaberMetni = kdGenel("haber")
intHaberKategorisi = kdGenel("kategori")
intHaberEditor = kdGenel("editor")
dtmHaberTarihi = kdGenel("tarih")
strHaberOzet = kdGenel("ozet")
strHaberBaslik = kdGenel("baslik")
End If
kdGenel.Close
End If
%>
<%=strSiteAdi%> | <%=strHaberBaslik%>
<%
'// Haber bulunamasıysa mesaj yazılıyor
If blnHaberVar = False Then
Response.Write "Yanlış Haber Numarası çağırdınız."
'// Haber varsa gösteriliyor
Else %>
<%=strHaberBaslik%>
Açıklama: <%=strHaberOzet%>
Kategori: <%=KategoriBul(intHaberKategorisi)%>
Eklenme Tarihi: <%=TarihFormatla(dtmHaberTarihi,0)%>
Geçerli Tarih: <%=TarihFormatla(Now(),1)%>
Site: <%=strSiteAdi%>
URL: <%=strSiteAdresi%><%=LinkVer("haber",strHaber, strHaberBaslik, KategoriBul(intHaberKategorisi))%>
<%=strHaberMetni%><%
End If %>