<%
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
' MyDesign Haber
' http://www.mydesign.gen.tr

' Fonksiyonlar Sayfası Kodları
' Son Düzenleme: 18 Aralık 2007 (v0.5.1)
'~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~


'// Zararlı Kodlardan Temizleme Fonksiyonu
Function Temizle(strVeri)

	'// Eğer Değişken Boşsa Fonksiyondan Çıkılıyor
	If IsNull(strVeri) Then Exit Function

	'// Zararlı Kodlar Burada Ayıklanıyor
	strVeri = Replace(strVeri, "&", "&amp;")
	strVeri = Replace(strVeri, "<", "&lt;")
	strVeri = Replace(strVeri, ">", "&gt;")
	strVeri = Replace(strVeri, "[", "&#091;")
	strVeri = Replace(strVeri, "]", "&#093;")
	strVeri = Replace(strVeri, """", "", 1, -1, 1)
	strVeri = Replace(strVeri, "=", "&#061;", 1, -1, 1)
	strVeri = Replace(strVeri, "'", "''", 1, -1, 1)
	Temizle = strVeri

End Function


'// Başlık Düzenleme Fonksiyonu
Function BaslikTemizle(strVeri)

	'// Eğer Değişken Boşsa Fonksiyondan Çıkılıyor
	If IsNull(strVeri) Then Exit Function

	'// Zararlı Kodlar Burada Ayıklanıyor
	strVeri = Replace(strVeri, "&", "&amp;")
	strVeri = Replace(strVeri, "<", "&lt;")
	strVeri = Replace(strVeri, ">", "&gt;")
	BaslikTemizle = strVeri

End Function

'// Mail Adresi Kontrolü Fonksiyonu
Function IsMail(strVeri)

	Dim objRegExp

	'// Eğer Değişken Boşsa Fonksiyondan Çıkılıyor
	If IsNull(strVeri) Then Exit Function

	'// Regular Expression Oluşturluyor	
	Set objRegExp = New Regexp
	With objRegExp
		'// RegExp Pattern: David Lott
		'// http://regexlib.com/REDetails.aspx?regexp_id=88
		.Pattern = "^([\w\-\.]+)@((\[([0-9]{1,3}\.){3}[0-9]{1,3}\])|(([\w\-]+\.)+)([a-zA-Z]{2,4}))$"
		.IgnoreCase = False
		.Global = True
	End With

	'// Adres Kontrol Ediliyor
	If objRegExp.Test(strVeri) = True Then
		IsMail = True
	Else
		IsMail = False
	End If

End Function


Function SifirEkle(ByVal strVeri)

	If strVeri = "" Then Exit Function
	If Len(Trim(strVeri)) < 2 Then strVeri = "0" & strVeri

	SifirEkle = strVeri

End Function

'// Tarih Formatlama Fonksiyonu
Function TarihFormatla(ByVal strTarih, ByVal blnSaat)

	'// Eğer Değişken Boşsa Fonksiyondan Çıkılıyor
	If IsNull(strTarih) Or isDate(strTarih) = False Then Exit Function

	'// Saat gösterimi ayarlanıyor
	If blnSaat <> 1 Then
		blnSaat = False
	Else
		blnSaat = True
	End If

	'// Gün ve Ay İsimleri Dizileri Hazırlanıyor
	Aylar = Array("","Ocak","Şubat","Mart","Nisan","Mayıs","Haziran","Temmuz","Ağustos","Eylül","Ekim","Kasım","Aralık")

	'// Tarihten Veriler Alınıyor
     	Dakika = Minute(strTarih)
     	Saat = Hour(strTarih)
     	Gun = Day(strTarih)
     	Ay = Month(strTarih)
     	Yil = Year(strTarih)

     	'// Biçimlendirmenin Bozulmaması İçin Değerler 2 Karakterden Kısaysa Başlarına 0 Ekleniyor
     	Gun = SifirEkle(Gun)
     	Saat = SifirEkle(Saat)
     	Dakika = SifirEkle(Dakika)

     	'// Eğer Girilen Tarihte Saat Yoksa Saat Kısmı Kaldırılıyor
     	If Dakika = "00" And Saat = "00" Then blnSaat = False
     	TarihFormatla = Gun &"&nbsp;"& Aylar(Ay) &"&nbsp;"& Yil
     	If blnSaat Then TarihFormatla = TarihFormatla &"&nbsp;"& Saat &":"& Dakika

End Function

'// Kullanıcı Adı Bulma Fonksiyonu
Function YazanBul(strVeri)

	'// Eğer Değişken Boşsa Fonksiyondan Çıkılıyor
	If IsNull(strVeri) Or IsNumeric(strVeri) = False Then Exit Function

	kdFonksiyon.Open "SELECT Kullanici, UyeID FROM tblUyeler WHERE UyeID = "& strVeri &"", adoCon, 1, 3
	If Not kdFonksiyon.EOF Then
		YazanBul = kdFonksiyon("kullanici")
	End If
	kdFonksiyon.Close

End Function

Function YazarBul(strVeri)

	'// Eğer Değişken Boşsa Fonksiyondan Çıkılıyor
	If IsNull(strVeri) Or IsNumeric(strVeri) = False Then Exit Function

	kdFonksiyon.Open "SELECT Ad, UyeID FROM tblUyeler WHERE UyeID = "& strVeri &"", adoCon, 1, 3
	If Not kdFonksiyon.EOF Then
		YazarBul = kdFonksiyon("Ad")
	End If
	kdFonksiyon.Close

End Function


Function AlanBul(strVeri)

	'// Eğer Değişken Boşsa Fonksiyondan Çıkılıyor
	If IsNull(strVeri) Or IsNumeric(strVeri) = False Then Exit Function

	kdFonksiyon.Open "SELECT Alan, Alan_ID FROM tblBannerAlanlar WHERE Alan_ID = "& strVeri &"", adoCon, 1, 3
	If Not kdFonksiyon.EOF Then
		AlanBul = kdFonksiyon("Alan")
	End If
	kdFonksiyon.Close

End Function


'// Kategori Bulma Fonksiyonu
Function KategoriBul(strVeri)

	'// Eğer Değişken Boşsa Fonksiyondan Çıkılıyor
	If IsNull(strVeri) Or IsNumeric(strVeri) = False Then Exit Function
	Dim kdFonksiyon2

	Set kdFonksiyon2 = Server.CreateObject("Adodb.Recordset")
	kdFonksiyon2.Open "SELECT katID, kategori FROM tblKategoriler WHERE katID = "& strVeri &"", adoCon, 1, 3
	If Not kdFonksiyon2.EOF Then
		KategoriBul = kdFonksiyon2("kategori")
	End If
	kdFonksiyon2.Close
	Set kdFonksiyon2 = Nothing

End Function


'// Kategori Bulma Fonksiyonu
Function UstKategoriBul(strVeri)

	'// Eğer Değişken Boşsa Fonksiyondan Çıkılıyor
	If IsNull(strVeri) Or IsNumeric(strVeri) = False Then Exit Function
	Dim kdFonksiyon2

	Set kdFonksiyon2 = Server.CreateObject("Adodb.Recordset")
	kdFonksiyon2.Open "SELECT katID, ustKatID FROM tblKategoriler WHERE katID = "& strVeri &"", adoCon, 1, 3
	If Not kdFonksiyon2.EOF Then
		UstKategoriBul = kdFonksiyon2("ustKatID")
	End If
	kdFonksiyon2.Close
	Set kdFonksiyon2 = Nothing

End Function

Function Buyut(strVeri)
	If IsNull(strVeri) Then Exit Function
	strVeri = Replace(strVeri, "ç", "Ç")
	strVeri = Replace(strVeri, "ğ", "Ğ")
	strVeri = Replace(strVeri, "ı", "I")
	strVeri = Replace(strVeri, "i", "İ")
	strVeri = Replace(strVeri, "ö", "Ö")
	strVeri = Replace(strVeri, "ş", "Ş")
	strVeri = UCase(strVeri)
	Buyut = strVeri
End Function


'// Onay Kodu oluşturma Fonksiyonu (WebWiz Forum)
Private Function hexValue(ByVal intHexLength)

	Dim strHexValue

	Randomize Timer()

	For intLooper = 1 to intHexLength

		intHexLength = CInt(Rnd * 1000) Mod 16

		Select Case intHexLength
			Case 1
				strHexValue = "1"
			Case 2
				strHexValue = "2"
			Case 3
				strHexValue = "3"
			Case 4
				strHexValue = "4"
			Case 5
				strHexValue = "5"
			Case 6
				strHexValue = "6"
			Case 7
				strHexValue = "7"
			Case 8
				strHexValue = "8"
			Case 9
				strHexValue = "9"
			Case 10
				strHexValue = "A"
			Case 11
				strHexValue = "B"
			Case 12
				strHexValue = "C"
			Case 13
				strHexValue = "D"
			Case 14
				strHexValue = "E"
			Case 15
				strHexValue = "F"
			Case Else
				strHexValue = "Z"
		End Select

		hexValue = hexValue & strHexValue
	Next
End Function


'// Yeni Satıra Geçme Fonksiyonu
Function Satir(byVal strVeri)

	If IsNull(strVeri) Then Exit Function

	strVeri = Replace(strVeri, vbCrLf, "<br />", 1, -1, 1)
	strVeri = Replace(strVeri, Chr(13), "<br />", 1, -1, 1)

	Satir = strVeri

End Function


'// Forum kodları fonksiyonu
Function MesajFormatla(byVal strMesaj)

	Dim DeyimBaslangici
	Dim DeyimSonu
	Dim strLink
	Dim strGeciciMesaj

	If IsNull(strMesaj) Then Exit Function

	'// HTML kodları düzenleniyor
	strMesaj = Replace(strMesaj, "<", "&lt;", 1, -1, 1)
	strMesaj = Replace(strMesaj, ">", "&gt;", 1, -1, 1)
	strMesaj = Replace(strMesaj, "       ", "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;", 1, -1, 1)
	strMesaj = Replace(strMesaj, "      ", "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;", 1, -1, 1)
	strMesaj = Replace(strMesaj, "     ", "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;", 1, -1, 1)
	strMesaj = Replace(strMesaj, "    ", "&nbsp;&nbsp;&nbsp;&nbsp;", 1, -1, 1)
	strMesaj = Replace(strMesaj, "   ", "&nbsp;&nbsp;&nbsp;", 1, -1, 1)
	strMesaj = Replace(strMesaj, vbTab, "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;", 1, -1, 1)
	strMesaj = Replace(strMesaj, Chr(10), "<br />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[B]", "<b>", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[/B]", "</b>", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[STRONG]", "<b>", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[/STRONG]", "</b>", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[U]", "<u>", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[/U]", "</u>", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[I]", "<i>", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[/I]", "</i>", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:)]", "<img src="""& strScriptYolu &"img/smiley/smiley1.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[;)]", "<img src="""& strScriptYolu &"img/smiley/smiley2.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:p]", "<img src="""& strScriptYolu &"img/smiley/smiley3.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:P]", "<img src="""& strScriptYolu &"img/smiley/smiley3.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:D]", "<img src="""& strScriptYolu &"img/smiley/smiley4.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:s]", "<img src="""& strScriptYolu &"img/smiley/smiley5.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:S]", "<img src="""& strScriptYolu &"img/smiley/smiley5.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:$]", "<img src=""i"& strScriptYolu &"mg/smiley/smiley6.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:D]", "<img src="""& strScriptYolu &"img/smiley/smiley7.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[LOL]", "<img src="""& strScriptYolu &"img/smiley/smiley8.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:(]", "<img src="""& strScriptYolu &"img/smiley/smiley9.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:^(]", "<img src="""& strScriptYolu &"img/smiley/smiley10.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:O]", "<img src="""& strScriptYolu &"img/smiley/smiley11.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:|]", "<img src="""& strScriptYolu &"img/smiley/smiley12.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[:x]", "<img src="""& strScriptYolu &"img/smiley/smiley13.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[}:)]", "<img src="""& strScriptYolu &"img/smiley/smiley14.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[L]", "<img src="""& strScriptYolu &"img/smiley/smiley15.gif"" alt="""" border=""0"" />", 1, -1, 1)
	strMesaj = Replace(strMesaj, "[%(]", "<img src="""& strScriptYolu &"img/smiley/smiley16.gif"" alt="""" border=""0"" />", 1, -1, 1)

	'// Mesajda [URL=  ile link hazırlanmışsa, ilgili adrese link veriliyor
	Do While InStr(UCase(strMesaj), "[URL=") > 0 AND InStr(UCase(strMesaj), "[/URL]") > 0

		DeyimBaslangici = InStr(strMesaj, "[URL=")
		DeyimSonu = InStr(DeyimBaslangici, UCase(strMesaj), "[/URL]") + 6
		If DeyimSonu < DeyimBaslangici Then DeyimSonu = DeyimBaslangici + 7
		strLink = Trim(Mid(strMesaj, DeyimBaslangici, (DeyimSonu - DeyimBaslangici)))
		strGeciciMesaj = strLink
		strGeciciMesaj = Replace(strGeciciMesaj, "[URL=", "<a href=""", 1, -1, 1)
		
		If InStr(UCase(strGeciciMesaj), "[/URL]") Then
			strGeciciMesaj = Replace(strGeciciMesaj, "[/URL]", "</a>", 1, -1, 1)
			strGeciciMesaj = Replace(strGeciciMesaj, "]", """ target=""_blank"">", 1, -1, 1)
		Else
			strGeciciMesaj = strGeciciMesaj & ">"
		End If

		strMesaj = Replace(strMesaj, strLink, strGeciciMesaj, 1, -1, 1)
	Loop

	'// Mesajda [URL]  ile link hazırlanmışsa, ilgili adrese link veriliyor
	Do While InStr(UCase(strMesaj), "[URL]") > 0  AND InStr(UCase(strMesaj), "[/URL]") > 0

		DeyimBaslangici = InStr(UCase(strMesaj), "[URL]")
		DeyimSonu = InStr(DeyimBaslangici, UCase(strMesaj), "[/URL]") + 6		
		If DeyimSonu < DeyimBaslangici Then DeyimSonu = DeyimBaslangici + 6
		strLink = Trim(Mid(strMesaj, DeyimBaslangici, (DeyimSonu - DeyimBaslangici)))
		strGeciciMesaj = strLink
		strGeciciMesaj = Replace(strGeciciMesaj, "[URL]", "", 1, -1, 1)
		strGeciciMesaj = Replace(strGeciciMesaj, "[/URL]", "", 1, -1, 1)		
		strGeciciMesaj = "<a href=""" & strGeciciMesaj & """ target=""_blank"">" & strGeciciMesaj & "</a>"
		strMesaj = Replace(strMesaj, strLink, strGeciciMesaj, 1, -1, 1)
	Loop

	MesajFormatla = strMesaj

End Function


Dim HepsindenOnce
Dim HepsindenSonra
Dim BasliktanOnce
Dim BasliktanSonra
Dim Sayi
Dim Kategori
Dim Sirala
Dim UstKategori
Dim AltKategoriAc

Sub KategoriListele(HepsindenOnce, HepsindenSonra, BasliktanOnce, BasliktanSonra, AktifKategori, AltKategoriAc, AltHepsindenOnce, AltHepsindenSonra, AltBasliktanOnce, AltBasliktanSonra)

	kdFonksiyon.Open "SELECT * FROM tblKategoriler WHERE goster = True AND ustKatID = 0 ORDER BY sira ASC, kategori ASC", adoCon, 1, 3
	If Not kdFonksiyon.Eof Then
		Response.Write HepsindenOnce
		Do While Not kdFonksiyon.Eof
			Response.Write BasliktanOnce &"<a href="""& LinkVer("kategori", kdFonksiyon("KatID"), "", KategoriBul(kdFonksiyon("KatID"))) &""">"& kdFonksiyon("kategori") &"</a>"
					
			If AltKategoriAc = True AND (CInt(AktifKategori) = kdFonksiyon("katID") OR CInt(UstKategoriBul(AktifKategori)) = kdFonksiyon("katID")) Then

				SQL = "SELECT * FROM tblKategoriler WHERE goster = True AND ustKatID = "& kdFonksiyon("katID") &" ORDER BY sira ASC, kategori ASC"
				kdYardimci.Open SQL, adoCon, 1, 3
				If Not kdYardimci.Eof Then
					Response.Write AltHepsindenOnce
					Do While Not kdyardimci.Eof
						Response.Write AltBasliktanOnce &"<a href="""& LinkVer("kategori", kdYardimci("KatID"), "", KategoriBul(kdYardimci("KatID"))) &""">"& kdYardimci("kategori") &"</a>"& AltBasliktanSonra
						kdYardimci.Movenext
					Loop
					Response.Write AltHepsindenSonra
				End If
				kdYardimci.Close
				
			End If
			Response.Write BasliktanSonra
			kdFonksiyon.Movenext
		Loop
		Response.Write HepsindenSonra
	End If
	kdFonksiyon.Close
	
End Sub


Sub SayfaListele(HepsindenOnce, HepsindenSonra, BasliktanOnce, BasliktanSonra)

	SQL = "SELECT Sayfa_ID, Baslik, Durum FROM tblSayfalar WHERE durum = True ORDER BY Baslik ASC"
	kdYardimci.Open SQL, adoCon, 1, 3
	If Not kdYardimci.EOF Then
		Response.Write HepsindenOnce
		Do While Not kdYardimci.EOF
			Response.Write(BasliktanOnce &"<a href="""& LinkVer("sayfa", kdYardimci("Sayfa_ID"), kdYardimci("Baslik"), "") &""">"& Trim(kdYardimci("Baslik")) &"</a>"& BasliktanSonra)
			kdYardimci.MoveNext
		Loop
		Response.Write HepsindenSonra
	End If
	kdYardimci.Close
		
End Sub


Sub BaslikListele(HepsindenOnce, HepsindenSonra, BasliktanOnce, BasliktanSonra, Sayi, Kategori, Sirala)

	If Sirala <> "okunma" Then Sirala = "tarih"

	SQL = "SELECT TOP "& Sayi &" baslik, okunma, durum, onay, haberID, tarih, kategori FROM tblHaberler WHERE durum = True AND onay = True AND kategori <> "& intKoseYazilari
	If Kategori <> "" AND IsNumeric(Kategori) Then SQL = SQL & "AND kategori = "& Kategori &" "
	SQL = SQL & " ORDER BY "& Sirala &" DESC"
	
	kdYardimci.Open SQL, adoCon, 1, 3
	If Not kdYardimci.EOF Then
		intLooper = 1
		Response.Write HepsindenOnce
		Do While Not kdYardimci.EOF AND intLooper <= Sayi
			Response.Write(BasliktanOnce &"<a href="""& LinkVer("haber", kdYardimci("haberID"), kdYardimci("baslik"), KategoriBul(kdYardimci("kategori"))) &""">"& Trim(kdYardimci("baslik")) &"</a>"& BasliktanSonra)
			kdYardimci.MoveNext
			intLooper = intLooper + 1
		Loop
		Response.Write HepsindenSonra
	End If
	kdYardimci.Close
		
End Sub


Sub DovizKurlari()

	Dim objVeriAl
	Dim Veri
	Dim strDolar
	Dim strEuro
	Dim strIMKB
	Dim arrVeriler
		
	Set objVeriAl = Server.CreateObject("Microsoft.XMLHTTP") 
	'objVeriAl.Open "GET" , "http://www.tcmb.gov.tr/kurlar/today.html", FALSE 
	objVeriAl.Open "GET", "http://www.mynet.com/include/finans/ticker/asp/smalldata.asp", FALSE
	objVeriAl.sEnd 
	Veri = objVeriAl.Responsetext 
	Set objVeriAl = Nothing
	
	arrVeriler = Split(Veri, ";")
	
	strDolar = arrVeriler(1)
	strEuro = arrVeriler(6)
	strIMKB = arrVeriler(12) %> 
	<table width="100%" cellpadding="3" cellspacing="0" style="background:url(img/doviz_bg.jpg) no-repeat; color:#fff; padding:0 0 0 10px">
	<tr>
		<td><b>PİYASALAR:</b></td>
		<td><b>Dolar:</b> <%=strDolar%></td>
		<td><b>Euro:</b> <%=strEuro%></td>
		<td><b>İMKB:</b> <%=strIMKB%></td></tr>
	</table><%
		
End Sub


Function jsTemizle(strVeri)

	strVeri = Replace(strVeri, "'", "", 1, -1, 1)
	strVeri = Replace(strVeri, vbCrLf, " ", 1, -1, 1)
	strVeri = Replace(strVeri, Chr(13), " ", 1, -1, 1)
	jsTemizle = strVeri
	
End Function


Function CreateURL(ByVal strVariable)

	Dim strTempURL

	strTempURL = Trim(strVariable)

	'// Türkçe karakterler değiştiriliyor
	strTempURL = Replace(strTempURL,"ç","c")
	strTempURL = Replace(strTempURL,"Ç","c")
	strTempURL = Replace(strTempURL,"ğ","g")
	strTempURL = Replace(strTempURL,"Ğ","g")
	strTempURL = Replace(strTempURL,"İ","i")
	strTempURL = Replace(strTempURL,"I","i")
	strTempURL = Replace(strTempURL,"ı","i")
	strTempURL = Replace(strTempURL,"ö","o")
	strTempURL = Replace(strTempURL,"Ö","o")
	strTempURL = Replace(strTempURL,"ş","s")
	strTempURL = Replace(strTempURL,"Ş","s")
	strTempURL = Replace(strTempURL,"ü","u")
	strTempURL = Replace(strTempURL,"Ü","u")

	strTempURL = LCase(Replace(strTempURL, " ", "-", 1, -1, 1))
	strTempURL = CleanChars(strTempURL)

	'// -- karakteri temizleniyor
	Do While InStr(strTempURL, "--")
		strTempURL = Replace(strTempURL, "--", "-", 1, -1, 1)
	Loop

	CreateURL = Left(strTempURL,50)

End Function

Function CleanChars(ByVal strVariable)

	Dim objRegExp
	Dim strTempValue

	Set objRegExp = New RegExp
	With objRegExp
		.Pattern = "([^a-zA-Z0-9\-])"
		.IgnoreCase = False
		.Global = True
		strTempValue = .Replace(strVariable, "")
	End With

	CleanChars = strTempValue

End Function

Function LinkVer(byVal strLinkTuru, byVal intHaberID, byVal strHaberBaslik, byVal strHaberKategori)

	If strLinkTuru = "haber" Then
		' Seçenekler
		'1: haber_detay.asp?haberID=id
		'2: /haber/id-baslik.html
		'3: /haber/id-kategori-baslik.html
	
		If LinkTuru = 1 Then
			LinkVer = ""& strScriptYolu &"haber_detay.asp?haberID="& intHaberID

		Elseif LinkTuru = 2 Then
			LinkVer = ""& strScriptYolu &"haber/"& intHaberID &"-"& CreateURL(strHaberBaslik) &".html"
	
		Elseif LinkTuru = 3 Then
			LinkVer = ""& strScriptYolu &"haber/"& intHaberID &"-"& CreateURL(strHaberKategori) &"-"& CreateURL(strHaberBaslik) &".html"
		End If
		
	Elseif strLinkTuru = "kategori" Then

		' Seçenekler
		'1: haberler.asp?katID=id
		'2: /haberler/id-kategori.html
	
		If LinkTuru = 1 Then
			LinkVer = ""& strScriptYolu &"haberler.asp?katID="& intHaberID

		Elseif LinkTuru = 2 OR LinkTuru = 3 Then
			LinkVer = ""& strScriptYolu &"haberler/"& intHaberID &"-"& CreateURL(strHaberKategori) &".html"
			
		End If

	Elseif strLinkTuru = "arsiv" Then

		' Seçenekler
		'1: arsiv.asp?katID=id
		'2: /arsiv/id-kategori.html

		' Sayfa numarası
		If strHaberBaslik = "" Or IsNumeric(strHaberBaslik) = False Then strHaberBaslik = 1

		If LinkTuru = 1 Then
			LinkVer = ""& strScriptYolu &"arsiv.asp?katID="& intHaberID &"&amp;s="& strHaberBaslik

		Elseif LinkTuru = 2 OR LinkTuru = 3 Then
			LinkVer = ""& strScriptYolu &"arsiv/"& intHaberID &"-"& strHaberBaslik &"-"& CreateURL(strHaberKategori) &".html"
			
		End If
		
	Elseif strLinkTuru = "anket" Then

		' Seçenekler
		'1: sonuclar.asp?AnketID=id
		'2: /sonuclar/id-soru.html
	
		If LinkTuru = 1 Then
			LinkVer = ""& strScriptYolu &"sonuclar.asp?AnketID="& intHaberID

		Elseif LinkTuru = 2 OR LinkTuru = 3 Then
			LinkVer = ""& strScriptYolu &"sonuclar/"& intHaberID &"-"& CreateURL(strHaberKategori) &".html"
			
		End If
	
	Elseif strLinkTuru = "sayfa" Then

		' Seçenekler
		'1: sayfa.asp?sayfaID=id
		'2: /sayfa/id-baslik.html
	
		If LinkTuru = 1 Then
			LinkVer = ""& strScriptYolu &"sayfa.asp?sayfaID="& intHaberID

		Elseif LinkTuru = 2 OR LinkTuru = 3 Then
			LinkVer = ""& strScriptYolu &"sayfa/"& intHaberID &"-"& CreateURL(strHaberBaslik) &".html"
			
		End If
	
	Elseif strLinkTuru = "yazar" Then

		' Seçenekler
		'1: yazar.asp?yaziID=id
		'2: /yazar/id-baslik.html
		'3: /yazar/id-yazar-baslik.html
	
		If LinkTuru = 1 Then
			LinkVer = ""& strScriptYolu &"yazar.asp?yaziID="& intHaberID

		Elseif LinkTuru = 2 Then
			LinkVer = ""& strScriptYolu &"yazar/"& intHaberID &"-"& CreateURL(strHaberBaslik) &".html"
			
		Elseif LinkTuru = 3 Then
			LinkVer = ""& strScriptYolu &"yazar/"& intHaberID &"-"& CreateURL(strHaberKategori) &"-"& CreateURL(strHaberBaslik) &".html"
		End If
	End If
	
End Function


Function KarakterBul(byVal strVeri, byVal strKarakter)

	Dim intSayi, intVeriUzunluk
	
	If strVeri = "" OR strKarakter = "" Then Exit Function
	
	intSayi = 0
	intVeriUzunluk = Len(strVeri)
	
	For intLooper = 1 To intVeriUzunluk
		If Mid(strVeri, intLooper, 1) = strKarakter Then
			intSayi = intSayi + 1
		End If
	Next
	
	KarakterBul = intSayi

End Function


Sub AnketSonuc(AnketID)

	Dim intGenislik

	kdFonksiyon.Open "SELECT * FROM tblAnketSorular WHERE Aktif = True AND Anket_ID = "& AnketID &" ORDER BY Tarih DESC", adoCon, 1, 3
	If Not kdFonksiyon.Eof Then 

		Dim intOySayisi

		kdYardimci.Open "SELECT SUM(Oy) AS Toplam FROM tblAnketSecenekler WHERE Anket_ID = "& kdFonksiyon("Anket_ID") &"", adoCon, 1, 3
		intOySayisi = kdYardimci("Toplam")
		kdYardimci.Close

		kdYardimci.Open "SELECT * FROM tblAnketSecenekler WHERE Anket_ID = "& kdFonksiyon("Anket_ID") &" ORDER BY Oy DESC", adoCon, 1, 3
		If Not kdYardimci.Eof Then 
			Response.Write "<p class=""anket-baslik"">"& kdFonksiyon("Soru") &"</p>"
			Do While Not kdYardimci.Eof

				If kdYardimci("Oy") = 0 Then
					intGenislik = 0
				Else
					intGenislik = kdYardimci("Oy")*100/intOySayisi
				End If %>
				<p><div class="oy_bg"><img src="<%=strScriptYolu%>img/oy_sol.gif" /><img src="<%=strScriptYolu%>img/oy.gif" height="7" width="<%=136*(intGenislik)/100%>" alt="%<%=Round(intGenislik,0)%>" /><img src="<%=strScriptYolu%>img/oy_sag.gif" /></div>
				<span class="yuzde">%<%=Round(intGenislik,0)%></span>&nbsp;<%=kdYardimci("Secenek")%></p><%
				kdYardimci.Movenext
			Loop
		End If
		kdYardimci.Close

	End If
	kdFonksiyon.Close
End Sub


Function BannerGoster(intBannerTur)

	If intBannerTur = "" OR IsNumeric(intBannerTur) = False Then Exit Function
	Dim bSQL, intRandNo, intBannerGosterim

	bSQL = "SELECT * FROM tblBanner "
	bSQL = bSQL & "WHERE Durum = True AND Baslangic <= #"& Date() &"# AND Bitis >= #"& Date() &"# AND Alan_ID = "& intBannerTur
	kdFonksiyon.Open bSQL, adoCon, 1, 3
	If kdFonksiyon.Eof Then
		'// Bu alana sabit reklam kodu ekleyebilirsiniz.
	Else
		' Rastgele banner seçimi
		Randomize
		intRandNo = Int((Rnd*kdFonksiyon.RecordCount)+0)
		kdFonksiyon.Move(intRandNo) 

		intBannerGosterim = kdFonksiyon("Gosterim")
		' Reklam HTML kodu ise
		If kdFonksiyon("HTML") = True Then
			Response.Write kdFonksiyon("Kod")

		Else
			Response.Write("<a href="""& strScriptYolu &"reklam_yonlendir.asp?rID="& kdFonksiyon("Banner_ID") &""" target="""& kdFonksiyon("Pencere") &""">" & _
			"<img src="""& kdFonksiyon("Resim") &""" alt="""& kdFonksiyon("Baslik") &""" style=""border:0; width:"& kdFonksiyon("Genislik") &";height:"& kdFonksiyon("Yukseklik") &""" /></a>")
		End If
		kdFonksiyon("Gosterim") = intBannerGosterim + 1
		kdFonksiyon.Update
	End If
	kdFonksiyon.Close

End Function
%>